m4에는 다양한 방법으로 문서를 처리하는 내장 매크로가 많이 있다.
가령, 문자열 중에서 일부분만을 뽑아낸다든지, 또는 검색한다든지,
대치한다든지 하는 등등의 기능이 있다.
len(string)
이것은 string의 길이(10진수)로 확장된다.
len() =>0 len(`abcdef') =>6
이 내장 매크로 len은 단지 인자가 있을 때에만 인식된다.
문자열 속에서 특정 문자열의 위치를 index로 찾을 수 있다.
index(string, substring)
이것은 string에서 substring이 처음으로 나타나는 인덱스로
확장된다. string의 첫 문자의 인덱스는 0이다. substring이
string 안에 나타나지 않는다면 index는 `-1'로 확장된다.
index(`gnus, gnats, and armadillos', `nat') =>7 index(`gnus, gnats, and armadillos', `dag') =>-1
내장 매크로 index는 인자가 있을 때에만 인식된다.
정규표현식 검색은 내장 매크로 regexp로 할 수 있다.
regexp(string, regexp, opt replacement)
이것은 string에서 regexp를 검색한다. 정규 표현식의 문법은 GNU Emacs에서와 동일하다. See section `Syntax of Regular Expressions' in The GNU Emacs Manual.
replacement가 생략된다면, regexp는 문자열에서 regexp와 첫 번째로 일치하는 인덱스로 확장된다. 문자열의 어디에서도 일치하는 regexp를 찾지 못했다면 `-1'로 확장된다.
regexp(`GNUs not Unix', `\<[a-z]\w+') =>5 regexp(`GNUs not Unix', `\<Q\w*') =>-1
replacement가 주어지면, regexp는 이 인자의 확장 문자열로 바뀌는데, `\n'는 (regexp의 n 번째 괄호 쳐진 부표현(sub-expression))에 의해 일치된 텍스트로 교체되고, `\&'는 전체 정규 표현식에 일치된 텍스트로 되도록 한다. (역자주: 원문이 너무 복잡해서 잘 번역된 것인지 모르겠습니다. 번역에 불만이 있으신 분들은 다음의 원문을 참고하시고 역자에게 더 좋은 번역 의견(또는 좀 더 극단적으로는, 원문 수정 의견)을 주시면 감사하겠습니다.
위 번역에 대한 원문:
If replacement is supplied, regexp changes the expansion
to this argument, with `\n' substituted by the text
matched by the nth parenthesized sub-expression of regexp,
`\&' being the text the entire regular expression matched.)
regexp(`GNUs not Unix', `\w\(\w+\)$', `*** \& *** \1 ***') =>*** Unix *** nix ***
내장 매크로 regexp는 단지 인자가 있을 때에만 인식된다.
문자열 중에서 부분-문자열은 substr로 뽑아낼 수 있다.
substr(string, from, opt length)
이것은 string의 부분-문자열로 확장된다. 그 부분-문자열은 string의 인덱스 from 값부터 시작하여 length 글자 수 만큼의 길이이며, 또는 length가 생략되었다면 string의 끝까지로 된다. 문자열에서 처음의 인덱스 값은 항상 0이다.
substr(`gnus, gnats, and armadillos', 6) =>gnats, and armadillos substr(`gnus, gnats, and armadillos', 6, 5) =>gnats
내장 매크로 substr은 인자가 있을 때에만 인식된다.
translit(string, chars, replacement)
이것은 string으로 확장되는데, 그 문자들 중에서 chars에도 나타나는 문자는 그 문자의 char에서의 위치와 같은 인덱스(위치)에 있는 replacement의 문자로 교체된다.
만일 replacement가 chars보다 짧다면, 남아도는 문자는 확장에서 없어진다. replacement가 생략되었다면, chars에 나타나는 모든 문자들은 string의 확장에서 제거된다.
chars와 replacement 둘 다 문자-범위를 포함할 수 있다. 예를 들면, `a-z'(모든 소문자를 뜻함), `0-9'(모든 숫자를 뜻함) 등이다. 줄문자(`-')를 하나의 일반 문자로서 chars나 replacement에 포함시키려면 그 문자열의 처음이나 마지막에 위치시켜야 한다.
문자의 범위에서 그 값이 처음보다 마지막이 더 `작은' 것은 에러가 아니다. (역자주: 원문에는 `작은'이 아닌 `큰'으로 되어 있는데, 문맥 상 명백한 오류로 보임) 이 경우에 그 범위는 거꾸로 될 것이다. 다시 말해, `9-0'은 `9876543210'을 의미한다.
translit(`GNUs not Unix', `A-Z') =>s not nix translit(`GNUs not Unix', `a-z', `A-Z') =>GNUS NOT UNIX translit(`GNUs not Unix', `A-Z', `z-a') =>tmfs not fnix
첫번째 예는 모든 대문자를 삭제하는 것이고, 두 번째 변환은 소문자를 대문자로 바꾸는 것이며, 세 번째는 모든 대문자의 (알파벳 순서를) `뒤집은' 소문자로 변환한 것이다. 처음 두 개의 경우는 매우 흔히 쓰인다.
내장 매크로 translit은 인자가 있을 경우에만 인식된다.
한 문자열에서의 포괄적인 치환은 patsubst를 사용한다.
patsubst(string, regexp, opt replacement)
이것은 string에서 regexp와 일치하는 부분을 찾고, 일치하는 부분 각각을 replacement로 치환한다. 정규 표현식의 문법은 GNU Emacs와 같다.
string에서 regexp와 일치하지 않는 부분은 확장 문자열로 그대로 복사된다. 일치하는 것이 발견된 후에는 언제나, 다음 검색은 그 일치했던 부분의 다음부터 진행된다. 따라서 string에서 각각의 문자는 절대로 두 번 대치되지 않는다. regexp가 길이가 0인 문자열과 일치한다면, 무한 루프가 되어 버리는 것을 막기 위해 다음 검색 시작 위치는 하나 증가된다. (역자주: 이런 기능은 문제가 될 소지가 있다. 무한 루프를 막기 위해서라면, 길이가 0인 문자열과의 일치는 아예 무시해 버리는 것이 더 나을 것 같은데.. 그런 일치를 처리해 주는 것이 정말 필요한 것일까?)
치환이 일어나게 될 때에는, replacement가 확장 결과에 삽입되는데, `\n'는 (regexp의 n 번째 괄호 쳐진 부표현(sub-expression))에 의해 일치된 텍스트로 교체되고, `\&'는 전체 정규 표현식에 일치한 텍스트로 되도록 한다.
replacement 인자는 생략될 수 있는데, 그렇게 하면 regexp에 일치하는 텍스트는 삭제된다.
patsubst(`GNUs not Unix', `^', `OBS: ') =>OBS: GNUs not Unix patsubst(`GNUs not Unix', `\<', `OBS: ') =>OBS: GNUs OBS: not OBS: Unix patsubst(`GNUs not Unix', `\w*', `(\&)') =>(GNUs)() (not)() (Unix) patsubst(`GNUs not Unix', `\w+', `(\&)') =>(GNUs) (not) (Unix) patsubst(`GNUs not Unix', `[A-Z][a-z]+') =>GN not
좀 더 실제적인 예를 들어보자. 이것은 개별적인 단어 또는 전체 문장을
(영문에서) 대소문자 교체하는 것인데, upcase와 downcase 매크로에
대한 호출을 교체하여 문자열로 만든다.
define(`upcase', `translit(`$*', `a-z', `A-Z')')dnl
define(`downcase', `translit(`$*', `A-Z', `a-z')')dnl
define(`capitalize1',
`regexp(`$1', `^\(\w\)\(\w*\)', `upcase(`\1')`'downcase(`\2')')')dnl
define(`capitalize',
`patsubst(`$1', `\w+', `capitalize1(`\&')')')dnl
capitalize(`GNUs not Unix')
=>Gnus Not Unix
내장 매크로 patsubst는 인자가 있을 때에만 인식된다.
format(format-string, ...)
이것은 C 함수인 printf와 아주 비슷하게 작동한다. 처음 인자는 형식 지정
문자열(format string)이고, 여기에는 `%' 지정문자(specification)가
포함될 수 있다. format은 형식화된 문자열로 확장된다.
그 사용법을 설명하는 가장 좋은 방법은 몇 개의 예를 드는 것이다.
define(`foo', `The brown fox jumped over the lazy dog') => format(`The string "%s" is %d characters long', foo, len(foo)) =>The string "The brown fox jumped over the lazy dog" is 38 characters long
forloop 매크로의 정의와 사용법은 See section 루프와 재귀. 이 예는
format으로 표 형식의 출력을 만들어 내는 방법을 보여준다.
forloop(`i', 1, 10, `format(`%6d squared is %10d ', i, eval(i**2))') => 1 squared is 1 => 2 squared is 4 => 3 squared is 9 => 4 squared is 16 => 5 squared is 25 => 6 squared is 36 => 7 squared is 49 => 8 squared is 64 => 9 squared is 81 => 10 squared is 100
format 내장 매크로는 ANSI C `printf' 함수를 본 따서
고안되었고, 표준적인 `%' 지정자와 그에 딸린 `c', `s', `d',
`o', `x', `X', `u', `e', `E', `f'를
지원한다. 이것은 또한 자리 폭과 정밀도, 그리고 `+', `-',
` ', `0', `#', `h', `l'과 같은 변경자를
제공한다. `printf'의 기능을 더 자세히 알고 싶으면, C 라이브러리 매뉴얼을
보시오.
Go to the first, previous, next, last section, table of contents.