보통의 텍스트로 확장하는, 아마도 호출 인자를 가질 수도 있는, 매크로만으로는 그다지 충분하지 못하다. 우리가 원하는 것은 실행-시(run-time)에 결정되는 조건 판단에 기초해서 다른 것들로 확장하는 매크로이다. 예를 들면 어떤 종류의 조건부-제어문(conditional)이 필요하다. 또한, 어떤 종류의 루프 구조가 있어서, 어떤 일을 여러 번, 또는 어떤 조건이 참인 동안만, 할 수 있으면 좋을 것이다.
m4에는 두 개의 다른 내장 조건문이 있다. 첫 번째는 ifdef이다.
ifdef(name, string-1, opt string-2)
이것은 매크로가 이미 정의가 되었는지 그렇지 않은지 판단하는 것이다.
name이 정의된 매크로의 명칭이라면 ifdef는
string-1으로 확장되고, 아니면 string-2로 확장된다.
string-2를 생략한다면, 그것은 (일반적인 규칙을 따라서) 빈 문자열이 된다.
ifdef(`foo', ``foo' is defined', ``foo' is not defined') =>foo is not defined define(`foo', `') => ifdef(`foo', ``foo' is defined', ``foo' is not defined') =>foo is defined
ifdef 매크로는 단지 인자가 있을 때에만 인식된다.
조건부-제어문 중 나머지는 ifelse인데, 이것은 훨씬 강력하다.
ifelse 는 긴 주석을 만든다든지, 또는 일반적인 if-else 와 같이
사용할 수도 있고 여러 개로 가지를 뻗을 수 있다. 이것은 전적으로
제공되는 인자의 갯수에 의존한다.
ifelse(comment) ifelse(string-1, string-2, equal, opt not-equal) ifelse(string-1, string-2, equal, ...)
하나의 인자만으로 ifelse를 사용한다면, ifelse 는 그 인자를
없애 버리며, 아무런 출력도 하지 않는다. 이것은 주석을 블록단위로 만들 때
여러 번 반복하여 dnl을 사용하는 것에 대한 대안으로써 사용하는
m4의 일반적인 관습이다. 이런 특별한 사용법은 GNU m4가 인식하며,
그래서 이런 경우에 인자와 관련된 경고는 결코 발생되지 않는다.
세 개나 네 개의 인자를 줘서 호출한다면, ifelse는 string-1과
string-2가 (한 글자 한 글자 모두 다) 같을 경우는 equal로 확장되고
다른 경우는 not-equal로 확장된다.
ifelse(foo, bar, `true') => ifelse(foo, foo, `true') =>true ifelse(foo, bar, `true', `false') =>false ifelse(foo, foo, `true', `false') =>true
ifelse는 네 개보다 더 많은 인자를 가질 수 있다. 네 개보다 많은
인자가 주어진다면 ifelse는 case나 switch 구문과
같은 전통적인 프로그래밍 언어와 같이 작동한다. string-1과
string-2가 같다면 ifelse는 equal로 확장되고, 그렇지 않은
경우는 첫 세 개의 인자를 건너뛰고 앞의 과정을 다시 되풀이 한다. 여기에
간단한 예를 들 필요가 있겠다. :
ifelse(foo, bar, `third', gnu, gnats, `sixth', `seventh') =>seventh
자연히, 실제의 경우는 위의 예제보다는 좀 더 복잡한 양상을 띠게 될 것이다.
ifelse를 일반적으로 쓰는 경우 중의 하나는 다양한 종류의 루프를
구현하는 매크로를 만들 때이다.
ifelse 매크로는 인자가 있을 때에만 인식된다.
m4에서는 루프를 직접 제공하지 않는다. 하지만 매크로는
재귀적으로 될 수 있다. 재귀호출 단계의 갯수에는 제한이 없다. 여러분의
하드웨어나 운영체제에 의해 제한되는 것은 제외하고는...
루프는, 재귀 호출과 앞에서 설명한 조건문을 이용하여, 프로그래밍될 수 있다.
shift라는 내장 매크로가 있는 데 이것이 하는 역할은, 여러 가지가 있지만
그 중에서, 매크로가 호출될 때 주어진 인자들을
돌려가며 되풀이(iterate through) 하는 데에 쓰인다.
shift(...)
괄호안에는 어떠한 개수의 인자도 올 수 있으며, 첫 번째 인자를 빼 버리고 모두 확장되며 각각의 인자들은 따옴표로 둘러싸이고, 쉼표로 분리된다.
shift(bar) => shift(foo, bar, baz) =>bar,baz
실전에서의 shift의 사용 예는 다음의 매크로인데, 여기서는 각각의 인자의
순서를 거꾸로 만들고 있다.
define(`reverse', `ifelse($#, 0, , $#, 1, ``$1'', `reverse(shift($@)), `$1'')') => reverse => reverse(foo) =>foo reverse(foo, bar, gnats, and gnus) =>and gnus, gnats, bar, foo
별로 흥미있는 예는 아니지만, 위의 것은 shift와 ifelse와
재귀호출로 간단한 루프를 만들 수 있다는 것을 보여준다.
(역자주: 이 매뉴얼의 앞부분('이 매뉴얼의 사용' 절 (node 이름은 '매뉴얼'임)에
밝힌 대로 forloop는 사용자-정의 매크로이며, 좀 더 뒤에 이것을 정의하는
방법에 대해 설명이 나오므로 끝까지 읽기 바람.)
이제 루프 매크로 forloop을 사용하는 간단한 예제를 보자. 예에서 보는 바와 같이 이것은 간단한 숫자세기를 한다.
forloop(`i', 1, 8, `i ') =>1 2 3 4 5 6 7 8
인자는 차례대로 반복 변수, 초기 값, 마지막 값, 매 회 확장될
텍스트이다. 여기에서 매크로 i는 단지 루프내부에서만 정의된다.
루프가 끝난 후에는 이전에 가졌었을 지도 모르는 그 값을 그대로 유지한다.
For-loop는 다음과 같이 중첩될 수 있다.
forloop(`i', 1, 4, `forloop(`j', 1, 8, `(i, j) ') ') =>(1, 1) (1, 2) (1, 3) (1, 4) (1, 5) (1, 6) (1, 7) (1, 8) =>(2, 1) (2, 2) (2, 3) (2, 4) (2, 5) (2, 6) (2, 7) (2, 8) =>(3, 1) (3, 2) (3, 3) (3, 4) (3, 5) (3, 6) (3, 7) (3, 8) =>(4, 1) (4, 2) (4, 3) (4, 4) (4, 5) (4, 6) (4, 7) (4, 8) =>
forloop 매크로의 구현은 매우 간단명료하다. forloop 그 자체는
단순한 포장일 뿐이며, 그 포장에서는 첫 번째 인자의 예전의 정의를 저장하고,
내부적인 매크로인 _forloop를 호출하고, 아까 저장해 놓았던 첫 번째
인자의 정의를 되돌려 놓는다.
_forloop 매크로는 네 번째 인자를 한 번 확장한 후, (루프가) 끝났는지를
검사한다. 아직 끝나지 않앗다면, (미리 정의된 매크로 incr을 이용하여,)
반복 변수를 증가시키고, 자신을 재귀호출 한다. (see section 증가와 감소 연산자)
여기에 forloop를 정의한 유용한 매크로가 있다.
define(`forloop', `pushdef(`$1', `$2')_forloop(`$1', `$2', `$3', `$4')popdef(`$1')') define(`_forloop', `$4`'ifelse($1, `$3', , `define(`$1', incr($1))_forloop(`$1', `$2', `$3', `$4')')')
따옴표를 주의 깊게 사용한 것을 눈 여겨 보라. 세 개의 인자만이 따옴표가 없는데, 각각에는 나름대로 이유가 있다. 이들 세 개의 인자에 왜 따옴표가 없는 지를 알려면, 따옴표로 묶었다면 어떤 일이 일어나는 지를 살펴보면 된다.
이제, 이들 두 매크로가 유용하기는 할 지라도, 그래도 일반적인 사용에는 충분히 튼튼하지는 않다. 그것들에는 마지막 값이 초기 값보다 작을 때라든가, 첫 번째 인자가 명칭이 될 수 없는 것이 주어질 경우와 같은 기초적인 오류 처리가 미약하다. 이들 오류를 바로 잡는 일은 독자들에게 연습문제로 남겨둔다.
Go to the first, previous, next, last section, table of contents.