매크로는 여러 다른 방법으로 정의, 재정의되거나 삭제될 수 있다. 또한 이전의 값을 잃어버리지 않고 매크로를 재정의하는 것이 가능하며 나중에 다시 되돌려 놓을 수도 있다.
정의하거나 재정의하는 일반적인 방법은 내장 매크로인 define을
사용하는 것이다.
define(name [, expansion])
위에서 name은 expansion으로 확장되는 것으로 정의된다. 만일 expansion이 주어지지 않는다면 name은 텅 빈 것으로 정의된다.
define은 확장되지 않는다.
다음의 예는 매크로 foo를 텍스트 `Hello World.'로 정의한다.
define(`foo', `Hello world.') => foo =>Hello world.
위에서 빈 줄이 나타나는 것은 줄바꿈(newline) 문자는 매크로 정의의 일부분이
아니라서 출력으로 복사된 것이다. 이것은 매크로 dnl을 사용하여 제거할
수 있다. 자세한 것은 See section 입력에서 공백문자 제거하기.
define 매크로는 인자가 있을 때에만 인식된다.
매크로는 인자를 가질수 있다. n번째 인자는 확장 텍스트에서
$n으로 사용하며 이것은 매크로가 확장될 때 n번째의 실제적인
인자로 교체된다. 여기에 두 개의 인자를 가지는 매크로의 예제가 있다.
이것은 단순히 두 개의 인자의 순서를 맞바꾸는 것이다.
define(`exch', `$2, $1') => exch(arg1, arg2) =>arg2, arg1
만약 define으로 전달되는 인자를 맞바꾸고자 한다면 아래 예에서와 같이
사용할 수 있다.
define(`exch', `$2, $1') => define(exch(``expansion text'', ``macro'')) => macro =>expansion text
따옴표를 두 겹으로 둘러싼 이유에 대한 설명을 보려면 See section 매크로의 인자를 따옴표로 묶기.
GNU m4는 `$' 다음에 한 자릿수 이상의 숫자를 쓸 수 있다.
매크로는 인자의 수에는 제한이 없다. 이 점이 한 자릿수만 쓸 수 있는 UNIX
버전의 m4와는 다른 점이다.
특별한 경우로, 0번째 인자를 뜻하는 $0은 항상 매크로 자신의 이름으로
확장된다는 점이다.
define(`test', ``Macro name: $0'') => test =>Macro name: test
만일 확장된 텍스트안에 따옴표로 둘러싸인 텍스트를 넣고 싶다면, 그 따옴표는 따옴표로 둘러싸인 문자열 속에 내장되어야 한다. 다음과 같이,
define(`foo', `This is macro `foo'.') => foo =>This is macro foo.
확장된 텍스트 안에 있는 `foo'는 확장되지 않는다. 그것이 따옴표로 묶여져 있는 한, 더 이상 명칭이 아니다.
실제로 주어진 인자의 개수와 실제로 주어진 인자 전체를 표현할 수 있는 특별한 표기법이 있다.
매크로 호출할 때에 실제로 주어진 인자의 개수는 확장 텍스트에서 $#으로
표시된다. 그래서, 주어진 인자의 개수를 보여주는 매크로는 다음과 같이 만든다.
define(`nargs', `$#') => nargs =>0 nargs() =>1 nargs(arg1, arg2, arg3) =>3
$* 표기법은 확장된 텍스트에서 모든 실제로 주어진 인자를 나타낼 수
있도록 해주며, 따옴표 없이, 사이에 쉼표가 온다. 예를 들면
define(`echo', `$*') => echo(arg1, arg2, arg3 , arg4) =>arg1,arg2,arg3 ,arg4
가끔 각각의 인자를 따옴표로 둘러쌀 필요성이 있다면 $@ 표기법을
사용하면 된다. 이것은 각각의 인자를 따옴표로 둘러싼다는 것만 제외하면
$* 과 같다. 간단한 예를 하나 들어보자.
define(`echo', `$@') => echo(arg1, arg2, arg3 , arg4) =>arg1,arg2,arg3 ,arg4
어 이런, 따옴표들은 다 어디로 갔지? 물론 이것들은 확장된 텍스트를
m4가 다시 읽을 때에 다 삼켜져 버렸다. 그 차이를 보여 주려면
다음과 같이 해보자.
define(`echo1', `$*') => define(`echo2', `$@') => define(`foo', `This is macro `foo'.') => echo1(foo) =>This is macro This is macro foo.. echo2(foo) =>This is macro foo.
이해가 잘되지 않는다면, See section 매크로 호출을 추적하기.
확장된 텍스트에서의 `$' 기호 다음에 m4가 이해하는 어떤 기호도
따라오지 않는다면, 이것을 다른 일반 텍스트처럼 매크로 확장 결과에 단순히 복사해
넣는다.
define(`foo', `$$$ hello $$$') => foo =>$$$ hello $$$
매크로를 써서 `$12'와 같은 것으로 확장하기를 바란다면, $
다음에 한쌍의 따옴표를 써주면 된다. 이것은 m4로 하여금
$ 부호를, 인자를 나타내는 기호로, 해석하지 않도록 한다.
하나의 매크로 정의는 undefine으로 삭제될 수 있다.
undefine(name)
name은 삭제될 매크로 명칭이다. 매크로 명칭은 보통 따옴표로 둘러싸는 것이 필요한데, 그렇게 하지 않으면 확장될 것이기 때문이다.
undefine은 확장되지 않는다.
foo =>foo define(`foo', `expansion text') => foo =>expansion text undefine(`foo') => foo =>foo
name이 아무런 매크로 정의도 가지지 않았다고 해도 에러가 아니며,
그 경우에 undefine은 아무 일도 하지 않는다.
undefine 매크로는 인자가 있을 때에만 인식된다.
이미 정의된 매크로는 그 명칭을 변경할 수 있다. 내장 매크로 defn이
이런 일을 한다.
defn(name)
이것은 따옴표가 붙은 name의 정의로 확장된다. 정의된 매크로가 아닌 것을 인자로 넣으면, 확장이 되지 않는다.
name이 사용자-정의 매크로라면, 따옴표로 둘러싸인 정의는 단순히
그 매크로의 확장 결과인 텍스트를 따옴표로 둘러싼 것으로 된다. name이
내장 매크로라면 그 확장은 특별한 토큰이 되는데, 그것은 그 내장 매크로의
내부적인 정의를 가리키는 것이다. 이 토큰은 define (그리고
pushdef)의 두 번째 인자로 쓰였을 때에만 의미가 있고, 다른 문맥에서
사용되었다면 무시된다.
이해하기에 가장 좋은 방법은 사용 예를 보는 것이다.
아래는 undefine을 zap으로 바꾸는 방법을 보여준다.
define(`zap', defn(`undefine')) => zap(`undefine') => undefine(`zap') =>undefine(zap)
이런 식으로, defn은 매크로 정의나 내장 매크로의 정의를 복사하는
데에 사용될 수 있다. 원래의 매크로가 제거되었다 할지라도 새로 붙여진 이름은
그 정의에 접근하는데 사용될 수 있다.
defn 매크로는 인자가 있을 때에만 인식된다.
매크로를 임시로 다시 정의하고, 이전의 정의로 나중에 되돌려 놓을 수 있다.
이러한 일을 하는 것은 내장 매크로 pushdef와 popdef이다.
pushdef(name [, expansion]) popdef(name)
이것은 define과 undefine사이의 관계와 아주 유사하다.
이 매크로는 스택과 비슷하게 작동한다. 어떤 하나의 매크로가 pushdef를
사용하여 임시로 재정의되고, 그것은 이미 존재하는 name의 정의를 다른
것으로 변경하는 한편, 새로운 정의가 설치되기 전에, 예전의 정의를 저장한다.
예전의 정의가 존재하지 않는 경우에는, pushdef는 define과
정확히 같은 행동을 한다.
어떤 하나의 매크로가 여러개의 정의를 가지고 있다고 가정하자. (당연히 그
중 하나의 정의만 사용할 수 있다.) 가장 꼭대기의 정의는
popdef로 제거할 수 있다. 예전의 정의가 존재하지 않는 경우에는,
popdef는 undefine과 정확히 같은 행동을 한다.
define(`foo', `Expansion one.') => foo =>Expansion one. pushdef(`foo', `Expansion two.') => foo =>Expansion two. popdef(`foo') => foo =>Expansion one. popdef(`foo') => foo =>foo
여러개의 정의가 있는 어떤 하나의 매크로가 define으로 재정의된다면,
최상위의 정의는 새로운 정의로 대치된다. 그 정의가 undefine으로
제거된다면, 최상위 하나만이 아닌, 모든 정의가 사라지게 된다.
define(`foo', `Expansion one.') => foo =>Expansion one. pushdef(`foo', `Expansion two.') => foo =>Expansion two. define(`foo', `Second expansion two.') => foo =>Second expansion two. undefine(`foo') => foo =>foo
내장 매크로 pushdef와 defn을 써서 임시로 재정의하는 것이
가능하다.
pushdef와 popdef 매크로는 인자가 있을 때에만 인식된다.
어떤 매크로든지 indir로 간접적으로 호출할 수 있다.
indir(name, ...)
이것은 매크로 name을 호출하게 되며, 그것에 나머지 인자가 건네진다.
이것은 규칙에 어긋나는 명칭(define은 그러한 명칭이 정의되는 것을
허용한다)을 가진 매크로 호출에 사용된다.
define(`$$internal$macro', `Internal macro (name `$0')') => $$internal$macro =>$$internal$macro indir(`$$internal$macro') =>Internal macro (name $$internal$macro)
여기에서의 요점은 커다란 매크로 패키지에서 그 내부에서만 쓰려고 사사로이
정의한 매크로가 있을 수 있는데, (역자주: 그것을 위에서 정의하는 것과 같이
일부러 규칙에 어긋나는 이름으로 정의한다고 했을 때,) 그것이 (역자주: 패키지
외부에서) 사고로 인해 호출되는 일은 없을 것이라는 것이다. 그것들은
반드시 내장 매크로 indir로만 호출될 수 있을 것이기
때문이다.
내장 매크로는 builtin을 사용하여 간접적으로 호출할 수 있다.
builtin(name, ...)
이렇게 하면 내장 매크로 name을 호출하게 되고, 거기에 그 나머지 인자가 건네진다. 이렇게 쓸 필요가 있는 경우란, 만약 name의 원래 정의에 다른 정의가 덮어 씌워져 버린 상태일 때 (역자주: 그럼에도 불구하고 원래의 정의로 호출을 하고 싶을 때) 이렇게 사용할 수 있을 것이다.
builtin 매크로는 인자가 있을 때에만 인식된다.
Go to the first, previous, next, last section, table of contents.